説明

イメージを作成し、透明色を設定します。

戻り値

イメージオブジェクト

シンタックス

imageMakeColorTransparent(imgcolor__)

履歴

ColdFusion(2016 年リリース):カラー値の配列として color パラメーターを使用します。

ColdFusion 10:この関数が追加されました。

プロパティ

パラメーター

説明

img

必須。オペレーションの対象になる ColdFusion イメージです。

color

必須。透明色です。

  • RGB カラーの 16 進数値。例えば、白の場合は "##FFFFFF" または "FFFFFF" を指定します。
  • 色の文字列値("black", "red", "green" など)。
  • 光の三原色(R,G,B)を表す値のリスト。各値の範囲は 0 ~ 255 である必要があります。

複数の透明色は配列を使用して指定できます。

例 1

<cfset myImage=ImageNew("",200,110)> 
<!--- Set the drawing color to green. ---> 
<cfset ImageSetDrawingColor(myImage,"green")> 
<!--- Turn on antialiasing to improve image quality. ---> 
<cfset ImageSetAntialiasing(myImage,"on")> 
<!--- Draw a filled green oval on the image. ---> 
<cfset ImageDrawOval(myImage,5,5,190,100,"yes")> 
<!--- Display the image in a browser. ---> 
<cfoutput>PNG image<br></cfoutput> 
<cfset ImageWrite(myImage,"#expandpath('.')#/png.png")> 
<cfset myImage = ImageRead("#expandpath('.')#/png.png")> 
<cfimage source="#myImage#" action="writeToBrowser" > 
<cfset x =ImageMakeColorTransparent(myImage,"green")> 
<cfimage source="#x#" action="writeToBrowser" >

例 2

次の例では、RGB カラーの配列が使用されています。 

<cfscript>
	myImage = imageNew("", 200, 200);
	myImage = imageMakeColorTransparent(myImage,["255,255,0","123,123,123","0,0,10"]);
	cfimage(action="writeToBrowser", source=myImage);
</cfscript>

例 3

次のコード例では、ソースイメージを透明にするために、複数の色の配列をどのように使用するかを確認できます。

<cfscript>
	// create array of transparent colors
	arrayOfColors=["237,27,36","35,177,77","255,127,38","112,146,191","254,174,201","185,122,87"];
	imgObj = imageRead("path/to/image/sample.jpg");
	cfimage(action="writeToBrowser", source=imgObj);
	img2=ImageMakeColorTransparent(imgObj,arrayOfColors);
	cfimage(action="writeToBrowser", source=img2);
</cfscript>

出力

入力イメージ

入力イメージ
入力イメージ

出力イメージ

出力イメージ
出力イメージ

本作品は Creative Commons Attribution-Noncommercial-Share Alike 3.0 Unported License によってライセンス許可を受けています。  Twitter™ および Facebook の投稿には、Creative Commons の規約内容は適用されません。

法律上の注意   |   プライバシーポリシー