Description

Encrypts a string using a specific algorithm and encoding method.

Returns

String; can be much longer than the original string.

Category

Security functionsString functions

Function syntax

Encrypt(string,key,[algorithm=CFMX_COMPAT,encoding=UU,IV="",iterations=0])

See also

Decrypt,EncryptBinary,DecryptBinary

History

ColdFRusion (2018 release): Introduced named parameters.

ColdFusion 8: Added support for encryption using the RSA BSafe Crypto-J library on Enterprise Edition.

ColdFusion MX 7.01: Added the IVorSalt and iterations parameters.

ColdFusion MX 7: Added the algorithm and encoding parameters.

Parameters

Parameter

Description

string

String to encrypt.

key

String. Key or seed used to encrypt the string.

 

  • For the CFMX_COMPAT algorithm, any combination of any number of characters; used as a seed used to generate a 32-bit encryption key.

  • For all other algorithms, a key in the format used by the algorithm. For these algorithms, use theGenerateSecretKeyfunction to generate the key.

 

algorithm

(Optional) The algorithm to use to encrypt the string.

The Enterprise Edition of ColdFusion installs the RSA BSafe Crypto-J library, which provides FIPS-140 Compliant Strong Cryptography. It includes the following algorithms:

 

  • AES: the Advanced Encryption Standard specified by the National Institute of Standards and Technology (NIST) FIPS-197.

  • DES: the Data Encryption Standard algorithm defined by NIST FIPS-46-3.

  • DES-EDE: the "Triple DES" algorithm defined by NIST FIPS-46-3.

  • DESX: The extended Data Encryption Standard symmetric encryption algorithm.

 

 

 

  • RC2: The RC2 block symmetric encryption algorithm defined by RFC 2268.

  • RC4: The RC4 symmetric encryption algorithm.

  • RC5: The RC5 encryption algorithm.

  • PBE: Password-based encryption algorithm defined in PKCS #5.

 

 

In addition to these algorithms, you can use the algorithms provided in the Standard Edition of ColdFusion.

 

The Standard Edition of ColdFusion installs a cryptography library with the following algorithms:

 

  • CFMX_COMPAT: the algorithm used in ColdFusion MX and prior releases. This algorithm is the least secure option (default).

  • AES: the Advanced Encryption Standard specified by the National Institute of Standards and Technology (NIST) FIPS-197.

  • BLOWFISH: the Blowfish algorithm defined by Bruce Schneier.

  • DES: the Data Encryption Standard algorithm defined by NIST FIPS-46-3.

  • DESEDE: the "Triple DES" algorithm defined by NIST FIPS-46-3.

 

If you install a security provider with additional cryptography algorithms, you can also specify any of its string encryption and decryption algorithms.

encoding

(Optional; if you specify this parameter, also specify the algorithm parameter). The binary encoding in which to represent the data as a string.

 

  • Base64: the Base64 algorithm, as specified by IETF RFC 2045.

  • Hex: the characters A-F0-9 represent the hexadecimal byte values.

  • UU: the UUEncode algorithm (default).

 

IVorSalt

(Optional) Specify this parameter to adjust ColdFusion encryption to match the details of other encryption software. If you specify this parameter, also specify thealgorithmparameter.

 

  • For Block Encryption algorithms: This is the binary Initialization Vector value to use with the algorithm. The algorithm must contain a Feedback Mode other than ECB. This must be a binary value that is exactly the same size as the algorithm block size. Use the same value in theDecryptfunction to successfully decrypt the data.

  • For Password Based Encryption algorithms: This is the binary Salt value to transform the password into a key. The same value must be used to decrypt the data.

 

iterations

(Optional) The number of iterations to transform the password into a binary key. Specify this parameter to adjust ColdFusion encryption to match the details of other encryption software. If you specify this parameter, also specify the algorithm parameter with a Password Based Encryption (PBE) algorithm. Do not specify this parameter for Block Encryption algorithms. Use the same value to encrypt and decrypt the data.

Usage

This function uses a symmetric key-based algorithm, in which the same key is used to encrypt and decrypt a string. The security of the encrypted string depends on maintaining the secrecy of the key.

The following are the FIPS-140 approved algorithms included in the RSA BSafe Crypto-J library that are used by ColdFusion. Some of these are not used with the encrypt function, but are used with other functions:

  • AES – ECB, CBC, CFB (128), OFB (128) – [128, 192, 256-bit key sizes]

  • AES – CTR

  • Diffie-Hellman Key Agreement

  • DSA

  • FIPS 186-2 General Purpose [(x-Change Notice); (SHA-1)]

  • FIPS 186-2 [(x-Change Notice); (SHA-1)]

  • HMAC-SHAx (where x is 1, 224, 256, 384, or 512)

  • RSA PKCS#1 v1.5 (sign, verify) (SHA-1,SHA-224,SHA-256,SHA-384,SHA-512)

  • Secure Hash Standard (SHA-1, SHA-224, SHA-256, SHA-384, SHA-512)

  • Triple DES - ECB, CBC, CFB (64 bit), and OFB (64 bit)

All algorithms included in the RSA BSafe Crypto-J library are available for use in the Enterprise Edition. In certain cases, you may want to disable some algorithms. To disable the DESX, RC5, and MD5PRNG algorithms, specify the following in the JVM arguments on the Java and JVM page of the ColdFusion Administrator:

-Dcoldfusion.enablefipscrypto=true

 

FIPS-140 approved cryptography is not available if you are running ColdFusion on WebSphere of JBoss.

To use the IBM/Lotus Sametime Instant Messaging Gateway in the Enterprise edition, disable the FIPS-140-only cryptography setting by specifying the following in the JVM arguments on the Java and JVM page of the ColdFusion Administrator:

-Dcoldfusion.disablejsafe=true

 

In Standard Edition, for all algorithms except the default algorithm, ColdFusion uses the Java Cryptography Extension (JCE) and installs a Sun Java runtime that includes the Sun JCE default security provider. This provider includes the algorithms listed in the Parameters section. The JCE framework includes facilities for using other provider implementations; however, Adobe cannot provide technical support for third-party security providers.

The default algorithm, which is the same one used in ColdFusion 5 and ColdFusion MX, uses an XOR-based algorithm that uses a pseudo-random 32-bit key, based on a seed passed by the user as a function parameter. This algorithm is less secure than the other available algorithms.

Example

The following example encrypts and decrypts a text string. It lets you specify the encryption algorithm and encoding technique. It also has a field for a key seed to use with the CFMX_COMPAT algorithm. For all other algorithms, it generates a secret key.

<h3>Encrypt Example</h3>
<!--- Do the following if the form has been submitted. --->
<cfif IsDefined("Form.myString")>
<cfscript>
/* GenerateSecretKey does not generate key for the CFMX_COMPAT algorithm,
so use the key from the form.
*/
if (Form.myAlgorithm EQ "CFMX_COMPAT")
theKey=Form.MyKey;
// For all other encryption techniques, generate a secret key.
else
theKey=generateSecretKey(Form.myAlgorithm);
//Encrypt the string
encrypted=encrypt(Form.myString, theKey, Form.myAlgorithm,
Form.myEncoding);
//Decrypt it
decrypted=decrypt(encrypted, theKey, Form.myAlgorithm, Form.myEncoding);
</cfscript>

<!--- Display the values used for encryption and decryption,
and the results. --->
<cfoutput>
<b>The algorithm:</b> #Form.myAlgorithm#<br>
<b>The key:</B> #theKey#<br>
<br>
<b>The string:</b> #Form.myString# <br>
<br>
<b>Encrypted:</b> #encrypted#<br>
<br>
<b>Decrypted:</b> #decrypted#<br>
</cfoutput>
</cfif>

<!--- The input form.--->
<form action="#CGI.SCRIPT_NAME#" method="post">
<b>Select the encoding</b><br>
<select size="1" name="myEncoding">
<option selected>UU</option>
<option>Base64</option>
<option>Hex</option>
</select><br>
<br>
<b>Select the algorithm</b><br>
<select size="1" name="myAlgorithm">
<option selected>CFMX_COMPAT</option>
<option>AES</option>
<option>DES</option>
<option>DESEDE</option>
</select><br>
<br>
<b>Input your key</b> (used for CFMX_COMPAT encryption only)<br>
<input type = "Text" name = "myKey" value = "MyKey"><br>
<br>
<b>Enter string to encrypt</b><br>
<textArea name = "myString" cols = "40" rows = "5" WRAP = "VIRTUAL">This string will be encrypted (you can replace it with more typing).
</textArea><br>
<input type = "Submit" value = "Encrypt my String">
</form>

 

<cfscript>
    myMessage = "Message to encrypt"
    key = generateSecretKey('AES');
    encryptedMsg = encrypt(myMessage,key,'AES', 'Base64');
    writeOutput(encryptedMsg);
</cfscript>

Output

JbRh2Ez58OJc9wpZUDefz0GZyDnA0/IMuV9qaRcFzCY=

This work is licensed under a Creative Commons Attribution-Noncommercial-Share Alike 3.0 Unported License  Twitter™ and Facebook posts are not covered under the terms of Creative Commons.

Legal Notices   |   Online Privacy Policy