Adobe Acrobat Sign でフィールド参照、リテラル、演算子および関数を使用して、計算フィールドの数式を作成します。
値の種類／計算済みで設定されたフィールドの数式プロパティに数式を入力します。この参考資料では、これらの数式を作成するために使用できる式の構文について説明します。
フィールド自体を設定するには、計算フィールドの作成を参照してください。
数式を作成する
数式には、次の要素の 1 つ以上を含めることができます：
| 要素 | 用途 | 例 |
|---|---|---|
| フィールド参照 | 別のフィールドの値を使用する | price * quantity |
| リテラル | 固定の数値、テキスト値、または日付を含める | total * 0.10 |
| オペレーター | 算術、比較、またはテキスト演算を実行する | subtotal + tax |
| 関数 | 事前定義された計算または論理演算を実行する | max(value1, value2) |
数式は他の計算フィールドも参照できます。
名前でフィールドを参照する
フィールドの名前を使用して、数式でその値を参照します。
次に例を示します。
price * quantity
price および quantity という名前のフィールドの値を使用します。
フィールド名にスペースが含まれている場合は、完全な名前を角括弧で囲みます：
[Unit price] * quantity
フォームが変更されても数式が理解しやすいように、意味のある一意のフィールド名を使用してください。
フィールド名の要件については、フォームフィールドプロパティを参照してください。
リテラル値を使用する
リテラルは数式に直接含まれる固定値です。
次に、例を示します。
- 数値：10
- テキスト: 「承認済み」
- サポートされている日付関数で使用される日付
テキスト文字列は一重引用符または二重引用符で囲みます。
次に例を示します。
"承認済み"
リテラル値はフィールド、演算子、関数と組み合わせることができます。
サポートされている演算子
演算子を使用して計算を実行し、テキストを結合し、値を比較します。
| オペレーター | 演算 |
|---|---|
| + | 追加 |
| - | 減算 |
| / | 区切る |
| * | 乗算 |
| & | テキスト文字列を結合 |
| = | 次に等しい |
| != | 次に等しくない |
| < | 不等号（より小） |
| <= | 次の値以下 |
| > | 不等号（大きい） |
| >= | 次の値以上 |
| % | 除算後の余りを返す |
| ^ | 値を累乗する |
比較演算子は、true または false の結果を返し、論理関数内で使用できます。
次に例を示します。
total >= 1000
total の値が 1000 以上かどうかを評価します。
数学関数
| 関数 | 結果 |
|---|---|
| abs(number1) | 数字の絶対値を返します。 |
| roundUp(number1) | 数値を切り上げます。 |
| roundDown(number1) | 数値を切り下げます。 |
| round(number1) | 数値を最も近い整数に丸めます。 |
| min(number1, number2) | 2 つのうち小さい方の数値を返します。 |
| max(number1, number2) | 2 つのうち大きい方の数値を返します。 |
例
max(Amount1, Amount2)
2 つのフィールド値のうち大きい方を返します。
日付関数
| 関数 | 結果 |
|---|---|
| datePart(part, date) | 日付の指定された部分を整数として返します。 |
| dateAdd(part, date, addition) | 日付に指定された数の日付部分を追加します。減算するには負の値を使用します。 |
| dateDiff(part, date1, date2) | 指定した日付部分を使用して、2 つの日付の差を返します。 |
| daysIn(part, date) | 日付の指定した部分の日数を返します。 |
| date(string) | 日付を表すテキスト値を、他の関数で使用できる日付値に変換します。 |
| now() | 数式が評価された日付と時間を返します。 |
日付部分の値
サポートされている日付関数で、部分引数に次の値を使用します。
| Value | 日付または時刻部分 |
|---|---|
| y | 年 |
| q | 四半期 |
| m | 月 |
| d | 日 |
| h | 時間 |
| n | 分 |
| s | 秒 |
例
dateAdd("d", StartDate, 30)
StartDate フィールドの値に 30 日を追加します。
前の日付を計算するには負の数を使用します：
dateAdd("d", StartDate, -7)
論理関数
計算値が 1 つ以上の条件に依存する場合は論理関数を使用します。
| 関数 | 結果 |
|---|---|
| if(logical_test, value_if_true, value_if_false) | テストが true の場合は 1 つの値を返し、false の場合は別の値を返します。 |
| and(logical1, logical2, ...) | 指定したすべての条件が true の場合にのみ true を返します。 |
| or(logical1, logical2, ...) | 指定した条件の少なくとも 1 つが true の場合に true を返します。 |
| not(logical) | true または false の結果を反転します。 |
| lookup(sourceField, values, default_value) | ソースフィールドに関連付けられた値を返すか、一致が見つからない場合はデフォルト値を返します。 |
if を使用して結果を選択します
次に例を示します。
if(Total >= 1000, "Approval required", "Approved")
Total が 1000 以上の場合は 1 つのテキスト値を返し、そうでない場合は別の値を返します。
true と false の結果自体に式を含めることができます。
論理テスト (and、or、not) の結合
すべての条件が true である必要がある場合は and を使用します:
and(Age >= 18, Consent = "Yes")
条件のいずれかが true である場合は or を使用します:
or(State = "CA", State = "OR")
条件の反対が必要な場合は not を使用します:
not(Status = "Closed")
lookup である値を別の値にマッピング
ソース値が対応する値を返す必要がある場合は lookup を使用します。
次に例を示します。
lookup(State, "CA=California,UT=Utah,WA=Washington", "Other")
一致が存在する場合はマッピングされた州名を返し、存在しない場合は Other を返します。
これは、ドロップダウンやラジオボタンフィールドなど、定義された選択肢のセットからソースの値が取得される場合に便利です。
数式の例
金額を計算
quantity * [Unit price]
量を単価で掛けます。
複数の値を追加
subtotal + tax + shipping
3 つのフィールドの値を追加します。
パーセンテージを計算
subtotal * taxRate
あるフィールドに、別のフィールドに保存されたレートを掛けます。
条件付きで値を返す
if(quantity >= 10, [Unit price] * 0.9, [Unit price])
量が定義されたしきい値に達した場合に、割引された値を返します。
将来の日付を計算
dateAdd("m", StartDate, 12)
StartDate から 12 か月後の日付を返します。
テキストを結合
RecipientName & " - " & Company
フィールド値とリテラルテキストを 1 つの結果に結合します。
保守しやすい数式を作成する
わかりやすいフィールド名を使用し、関連する計算をフォームで可能な限りシンプルに保ちます。
数式をレビューする際は、以下を確認してください：
- 参照されるフィールドがすべて存在する。
- フィールド名が数式で使用される名前と一致する。
- スペースを含むフィールドが角括弧で囲まれている。
- テキストリテラルが引用符で囲まれている。
- 関数に必要な引数が含まれている。
- 計算フィールドが、予想される受信者の入力に対して意図した値を生成する。
計算フィールドの設定と数値結果の書式設定については、計算フィールドの作成を参照してください。
