Adobe Acrobat Sign でフィールド参照、リテラル、演算子および関数を使用して、計算フィールドの数式を作成します。
値の種類／計算済みで設定されたフィールドの数式プロパティに数式を入力します。 このリファレンスでは、数式の作成に使用できる式の構文について説明します。
フィールド自体を設定するには、計算フィールドの作成を参照してください。
数式を作成する
数式には、以下の要素を 1 つ以上含めることができます：
| 要素 | 用途 | 例 |
|---|---|---|
| フィールド参照 | 別のフィールドの値を使用する | price * quantity |
| リテラル | 固定の数値、テキスト値、または日付を含める | total * 0.10 |
| オペレーター | 算術演算、比較演算、またはテキスト操作を実行する | subtotal + tax |
| 関数 | 定義済みの計算または論理演算を実行する | max(value1, value2) |
数式では、他の計算フィールドを参照することもできます。
名前でフィールドを参照する
フィールド名を使用して、数式内でその値を参照します。
次に例を示します。
price * quantity
price と quantity という名前のフィールドの値を使用します。
フィールド名にスペースが含まれている場合は、名前全体を角括弧で囲みます：
[Unit price] * quantity
フォームが変更されても数式が理解しやすいように、意味のある一意のフィールド名を使用してください。
フィールド名の要件については、フォームフィールドプロパティを参照してください。
リテラル値を使用する
リテラルとは、数式に直接含まれる固定値のことです。
次に、例を示します。
- 数値：10
- テキスト：「承認済み」
- サポートされている日付関数で使用される日付
文字列は一重引用符または二重引用符で囲みます。
次に例を示します。
"承認済み"
リテラル値は、フィールド、演算子、関数と組み合わせることができます。
サポートされている演算子
演算子を使用して、計算の実行、テキストの結合、値の比較を行います。
| オペレーター | 操作 |
|---|---|
| + | 追加 |
| - | 減算 |
| / | 区切る |
| * | 乗算 |
| & | 文字列を結合する |
| = | 次に等しい |
| != | 次に等しくない |
| < | 不等号（より小） |
| <= | 次の値以下 |
| > | 不等号（大きい） |
| >= | 次の値以上 |
| % | 除算後の余りを返す |
| ^ | 値をべき乗する |
比較演算子は、true または false の結果を返し、論理関数内で使用できます。
次に例を示します。
total >= 1000
total の値が 1000 以上かどうかを評価します。
数学関数
| 関数 | 結果 |
|---|---|
| abs(number1) | 数字の絶対値を返します。 |
| roundUp(number1) | 数値を切り上げます。 |
| roundDown(number1) | 数値を切り下げます。 |
| round(number1) | 数値を最も近い整数に丸めます。 |
| min(number1, number2) | 2 つのうち小さい方の数値を返します。 |
| max(number1, number2) | 2 つのうち大きい方の数値を返します。 |
例
max(Amount1, Amount2)
2 つのフィールド値のうち大きい方を返します。
日付関数
| 関数 | 結果 |
|---|---|
| datePart(part, date) | 日付の指定された部分を整数として返します。 |
| dateAdd(part, date, addition) | 日付の一部について指定された数を日付に加算します。減算するには負の値を使用します。 |
| dateDiff(part, date1, date2) | 指定された日付の部分を使用して 2 つの日付の差を返します。 |
| daysIn(part, date) | 日付の指定された部分の日数を返します。 |
| date(string) | 日付を表すテキスト値を、他の関数で使用できる日付値に変換します。 |
| now() | 数式が評価された日付と時間を返します。 |
日付部分の値
サポートされている日付関数で、部分引数に次の値を使用します。
| 値 | 日付または時刻の部分 |
|---|---|
| y | 年 |
| q | 四半期 |
| m | 月 |
| d | 日 |
| h | 時間 |
| n | 分 |
| s | 秒 |
例
dateAdd("d", StartDate, 30)
StartDate フィールドの値に 30 日を加算します。
負の数を使用すると、より前の日付を計算できます：
dateAdd("d", StartDate, -7)
論理関数
計算された値が 1 つ以上の条件に依存する場合は、論理関数を使用します。
| 関数 | 結果 |
|---|---|
| if(logical_test, value_if_true, value_if_false) | テストが true の場合は一方の値を返し、false の場合はもう一方の値を返します。 |
| and(logical1, logical2, ...) | 指定された条件がすべて true の場合にのみ true を返します。 |
| or(logical1, logical2, ...) | 指定された条件の少なくとも 1 つが true の場合に true を返します。 |
| not(logical) | true または false の結果を反転します。 |
| lookup(sourceField, values, default_value) | ソースフィールドに関連付けられた値を返すか、一致が見つからない場合はデフォルト値を返します。 |
結果を選択するには、if を使用します
次に例を示します。
if(Total >= 1000, "Approval required", "Approved")
Total が 1000 以上の場合は一方のテキスト値を返し、そうでない場合は他方を返します。
true の結果と false の結果には、それ自体に数式を含めることができます。
論理テストの組み合わせ（and、or、not）
すべての条件が true である必要がある場合は、and を使用します。
and(Age >= 18, Consent = "Yes")
いずれかの条件が true になれば良い場合は、or を使用します。
or(State = "CA", State = "OR")
条件の逆が必要な場合は、not を使用します。
not(Status = "Closed")
lookup である値を別の値にマッピング
ソース値が対応する値を返す必要がある場合は lookup を使用します。
次に例を示します。
lookup(State, "CA=California,UT=Utah,WA=Washington", "Other")
一致するものが存在する場合はマッピングされた州名を返し、存在しない場合は Other を返します。
これは、ドロップダウンやラジオボタンフィールドのように、ソースの値が定義済みの選択肢セットから取得される場合に役立ちます。
数式の例
金額を計算する
quantity * [Unit price]
量に単価を掛けます。
複数の値を加算する
小計 ＋ 税金 ＋ 配送料
3 つのフィールドの値を加算します。
割合を計算する
subtotal * taxRate
あるフィールドに、別のフィールドに保存されたレートを掛けます。
条件付きで値を返す
if(quantity >= 10, [Unit price] * 0.9, [Unit price])
量が定義済みのしきい値に達した場合に、割引された値を返します。
将来の日付を計算する
dateAdd("m", StartDate, 12)
StartDate から 12 ヶ月後の日付を返します。
テキストを結合する
RecipientName & " - " & Company
フィールド値とリテラルテキストを 1 つの結果に結合します。
保守しやすい数式を作成する
分かりやすいフィールド名を使用し、関連する計算はフォームが許す限りシンプルに保ちます。
数式を確認する際は、次の点を確認してください：
- 参照されているすべてのフィールドが存在すること。
- フィールド名が数式で使用されている名前と一致していること。
- スペースを含むフィールドが角かっこで囲まれていること。
- テキストリテラルが引用符で囲まれていること。
- 関数に必要な引数が含まれていること。
- 計算フィールドが、想定される受信者の入力に対して意図した値を生成すること。
計算フィールドの設定方法と数値結果の書式設定については、計算フィールドの作成を参照してください。
